Text file src/syscall/asm9_unix2_amd64.s

     1	// +build dragonfly freebsd
     2	
     3	// Copyright 2016 The Go Authors. All rights reserved.
     4	// Use of this source code is governed by a BSD-style
     5	// license that can be found in the LICENSE file.
     6	
     7	#include "textflag.h"
     8	#include "funcdata.h"
     9	
    10	//
    11	// Syscall9 support for AMD64, DragonFly and FreeBSD
    12	//
    13	
    14	// func Syscall9(trap int64, a1, a2, a3, a4, a5, a6, a7, a8, a9 int64) (r1, r2, err int64);
    15	TEXT	·Syscall9(SB),NOSPLIT,$0-104
    16		CALL	runtime·entersyscall(SB)
    17		MOVQ	num+0(FP), AX	// syscall entry
    18		MOVQ	a1+8(FP), DI
    19		MOVQ	a2+16(FP), SI
    20		MOVQ	a3+24(FP), DX
    21		MOVQ	a4+32(FP), R10
    22		MOVQ	a5+40(FP), R8
    23		MOVQ	a6+48(FP), R9
    24	
    25		// shift around the last three arguments so they're at the
    26		// top of the stack when the syscall is called.
    27		// note that we are scribbling over the Go arguments now.
    28		MOVQ	SP, CX	// hide (SP) writes from vet
    29		MOVQ	a7+56(FP), R11 // arg 7
    30		MOVQ	R11, 8(CX)
    31		MOVQ	a8+64(FP), R11 // arg 8
    32		MOVQ	R11, 16(CX)
    33		MOVQ	a9+72(FP), R11 // arg 9
    34		MOVQ	R11, 24(CX)
    35	
    36		SYSCALL
    37		JCC	ok9
    38		MOVQ	$-1, r1+80(FP)	// r1
    39		MOVQ	$0, r2+88(FP)	// r2
    40		MOVQ	AX, err+96(FP)	// errno
    41		CALL	runtime·exitsyscall(SB)
    42		RET
    43	ok9:
    44		MOVQ	AX, r1+80(FP)	// r1
    45		MOVQ	DX, r2+88(FP)	// r2
    46		MOVQ	$0, err+96(FP)	// errno
    47		CALL	runtime·exitsyscall(SB)
    48		RET

View as plain text