Text file src/runtime/sys_linux_arm64.s
1 // Copyright 2014 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 //
6 // System calls and other sys.stuff for arm64, Linux
7 //
8
9 #include "go_asm.h"
10 #include "go_tls.h"
11 #include "textflag.h"
12
13 #define AT_FDCWD -100
14
15 #define CLOCK_REALTIME 0
16 #define CLOCK_MONOTONIC 1
17
18 #define SYS_exit 93
19 #define SYS_read 63
20 #define SYS_write 64
21 #define SYS_openat 56
22 #define SYS_close 57
23 #define SYS_fcntl 25
24 #define SYS_nanosleep 101
25 #define SYS_mmap 222
26 #define SYS_munmap 215
27 #define SYS_setitimer 103
28 #define SYS_clone 220
29 #define SYS_sched_yield 124
30 #define SYS_rt_sigreturn 139
31 #define SYS_rt_sigaction 134
32 #define SYS_rt_sigprocmask 135
33 #define SYS_sigaltstack 132
34 #define SYS_madvise 233
35 #define SYS_mincore 232
36 #define SYS_getpid 172
37 #define SYS_gettid 178
38 #define SYS_kill 129
39 #define SYS_tgkill 131
40 #define SYS_futex 98
41 #define SYS_sched_getaffinity 123
42 #define SYS_exit_group 94
43 #define SYS_epoll_create1 20
44 #define SYS_epoll_ctl 21
45 #define SYS_epoll_pwait 22
46 #define SYS_clock_gettime 113
47 #define SYS_faccessat 48
48 #define SYS_socket 198
49 #define SYS_connect 203
50 #define SYS_brk 214
51
52 TEXT runtime·exit(SB),NOSPLIT|NOFRAME,$0-4
53 MOVW code+0(FP), R0
54 MOVD $SYS_exit_group, R8
55 SVC
56 RET
57
58 // func exitThread(wait *uint32)
59 TEXT runtime·exitThread(SB),NOSPLIT|NOFRAME,$0-8
60 MOVD wait+0(FP), R0
61 // We're done using the stack.
62 MOVW $0, R1
63 STLRW R1, (R0)
64 MOVW $0, R0 // exit code
65 MOVD $SYS_exit, R8
66 SVC
67 JMP 0(PC)
68
69 TEXT runtime·open(SB),NOSPLIT|NOFRAME,$0-20
70 MOVD $AT_FDCWD, R0
71 MOVD name+0(FP), R1
72 MOVW mode+8(FP), R2
73 MOVW perm+12(FP), R3
74 MOVD $SYS_openat, R8
75 SVC
76 CMN $4095, R0
77 BCC done
78 MOVW $-1, R0
79 done:
80 MOVW R0, ret+16(FP)
81 RET
82
83 TEXT runtime·closefd(SB),NOSPLIT|NOFRAME,$0-12
84 MOVW fd+0(FP), R0
85 MOVD $SYS_close, R8
86 SVC
87 CMN $4095, R0
88 BCC done
89 MOVW $-1, R0
90 done:
91 MOVW R0, ret+8(FP)
92 RET
93
94 TEXT runtime·write(SB),NOSPLIT|NOFRAME,$0-28
95 MOVD fd+0(FP), R0
96 MOVD p+8(FP), R1
97 MOVW n+16(FP), R2
98 MOVD $SYS_write, R8
99 SVC
100 CMN $4095, R0
101 BCC done
102 MOVW $-1, R0
103 done:
104 MOVW R0, ret+24(FP)
105 RET
106
107 TEXT runtime·read(SB),NOSPLIT|NOFRAME,$0-28
108 MOVW fd+0(FP), R0
109 MOVD p+8(FP), R1
110 MOVW n+16(FP), R2
111 MOVD $SYS_read, R8
112 SVC
113 CMN $4095, R0
114 BCC done
115 MOVW $-1, R0
116 done:
117 MOVW R0, ret+24(FP)
118 RET
119
120 TEXT runtime·usleep(SB),NOSPLIT,$24-4
121 MOVWU usec+0(FP), R3
122 MOVD R3, R5
123 MOVW $1000000, R4
124 UDIV R4, R3
125 MOVD R3, 8(RSP)
126 MUL R3, R4
127 SUB R4, R5
128 MOVW $1000, R4
129 MUL R4, R5
130 MOVD R5, 16(RSP)
131
132 // nanosleep(&ts, 0)
133 ADD $8, RSP, R0
134 MOVD $0, R1
135 MOVD $SYS_nanosleep, R8
136 SVC
137 RET
138
139 TEXT runtime·gettid(SB),NOSPLIT,$0-4
140 MOVD $SYS_gettid, R8
141 SVC
142 MOVW R0, ret+0(FP)
143 RET
144
145 TEXT runtime·raise(SB),NOSPLIT|NOFRAME,$0
146 MOVD $SYS_getpid, R8
147 SVC
148 MOVW R0, R19
149 MOVD $SYS_gettid, R8
150 SVC
151 MOVW R0, R1 // arg 2 tid
152 MOVW R19, R0 // arg 1 pid
153 MOVW sig+0(FP), R2 // arg 3
154 MOVD $SYS_tgkill, R8
155 SVC
156 RET
157
158 TEXT runtime·raiseproc(SB),NOSPLIT|NOFRAME,$0
159 MOVD $SYS_getpid, R8
160 SVC
161 MOVW R0, R0 // arg 1 pid
162 MOVW sig+0(FP), R1 // arg 2
163 MOVD $SYS_kill, R8
164 SVC
165 RET
166
167 TEXT runtime·setitimer(SB),NOSPLIT|NOFRAME,$0-24
168 MOVW mode+0(FP), R0
169 MOVD new+8(FP), R1
170 MOVD old+16(FP), R2
171 MOVD $SYS_setitimer, R8
172 SVC
173 RET
174
175 TEXT runtime·mincore(SB),NOSPLIT|NOFRAME,$0-28
176 MOVD addr+0(FP), R0
177 MOVD n+8(FP), R1
178 MOVD dst+16(FP), R2
179 MOVD $SYS_mincore, R8
180 SVC
181 MOVW R0, ret+24(FP)
182 RET
183
184 // func walltime() (sec int64, nsec int32)
185 TEXT runtime·walltime(SB),NOSPLIT,$24-12
186 MOVD RSP, R20 // R20 is unchanged by C code
187 MOVD RSP, R1
188
189 MOVD g_m(g), R21 // R21 = m
190
191 // Set vdsoPC and vdsoSP for SIGPROF traceback.
192 MOVD LR, m_vdsoPC(R21)
193 MOVD R20, m_vdsoSP(R21)
194
195 MOVD m_curg(R21), R0
196 CMP g, R0
197 BNE noswitch
198
199 MOVD m_g0(R21), R3
200 MOVD (g_sched+gobuf_sp)(R3), R1 // Set RSP to g0 stack
201
202 noswitch:
203 SUB $16, R1
204 BIC $15, R1 // Align for C code
205 MOVD R1, RSP
206
207 MOVW $CLOCK_REALTIME, R0
208 MOVD runtime·vdsoClockgettimeSym(SB), R2
209 CBZ R2, fallback
210 BL (R2)
211 B finish
212
213 fallback:
214 MOVD $SYS_clock_gettime, R8
215 SVC
216
217 finish:
218 MOVD 0(RSP), R3 // sec
219 MOVD 8(RSP), R5 // nsec
220
221 MOVD R20, RSP // restore SP
222 MOVD $0, m_vdsoSP(R21) // clear vdsoSP
223
224 MOVD R3, sec+0(FP)
225 MOVW R5, nsec+8(FP)
226 RET
227
228 TEXT runtime·nanotime(SB),NOSPLIT,$24-8
229 MOVD RSP, R20 // R20 is unchanged by C code
230 MOVD RSP, R1
231
232 MOVD g_m(g), R21 // R21 = m
233
234 // Set vdsoPC and vdsoSP for SIGPROF traceback.
235 MOVD LR, m_vdsoPC(R21)
236 MOVD R20, m_vdsoSP(R21)
237
238 MOVD m_curg(R21), R0
239 CMP g, R0
240 BNE noswitch
241
242 MOVD m_g0(R21), R3
243 MOVD (g_sched+gobuf_sp)(R3), R1 // Set RSP to g0 stack
244
245 noswitch:
246 SUB $32, R1
247 BIC $15, R1
248 MOVD R1, RSP
249
250 MOVW $CLOCK_MONOTONIC, R0
251 MOVD runtime·vdsoClockgettimeSym(SB), R2
252 CBZ R2, fallback
253 BL (R2)
254 B finish
255
256 fallback:
257 MOVD $SYS_clock_gettime, R8
258 SVC
259
260 finish:
261 MOVD 0(RSP), R3 // sec
262 MOVD 8(RSP), R5 // nsec
263
264 MOVD R20, RSP // restore SP
265 MOVD $0, m_vdsoSP(R21) // clear vdsoSP
266
267 // sec is in R3, nsec in R5
268 // return nsec in R3
269 MOVD $1000000000, R4
270 MUL R4, R3
271 ADD R5, R3
272 MOVD R3, ret+0(FP)
273 RET
274
275 TEXT runtime·rtsigprocmask(SB),NOSPLIT|NOFRAME,$0-28
276 MOVW how+0(FP), R0
277 MOVD new+8(FP), R1
278 MOVD old+16(FP), R2
279 MOVW size+24(FP), R3
280 MOVD $SYS_rt_sigprocmask, R8
281 SVC
282 CMN $4095, R0
283 BCC done
284 MOVD $0, R0
285 MOVD R0, (R0) // crash
286 done:
287 RET
288
289 TEXT runtime·rt_sigaction(SB),NOSPLIT|NOFRAME,$0-36
290 MOVD sig+0(FP), R0
291 MOVD new+8(FP), R1
292 MOVD old+16(FP), R2
293 MOVD size+24(FP), R3
294 MOVD $SYS_rt_sigaction, R8
295 SVC
296 MOVW R0, ret+32(FP)
297 RET
298
299 // Call the function stored in _cgo_sigaction using the GCC calling convention.
300 TEXT runtime·callCgoSigaction(SB),NOSPLIT,$0
301 MOVD sig+0(FP), R0
302 MOVD new+8(FP), R1
303 MOVD old+16(FP), R2
304 MOVD _cgo_sigaction(SB), R3
305 SUB $16, RSP // reserve 16 bytes for sp-8 where fp may be saved.
306 BL R3
307 ADD $16, RSP
308 MOVW R0, ret+24(FP)
309 RET
310
311 TEXT runtime·sigfwd(SB),NOSPLIT,$0-32
312 MOVW sig+8(FP), R0
313 MOVD info+16(FP), R1
314 MOVD ctx+24(FP), R2
315 MOVD fn+0(FP), R11
316 BL (R11)
317 RET
318
319 TEXT runtime·sigtramp(SB),NOSPLIT,$192
320 // Save callee-save registers in the case of signal forwarding.
321 // Please refer to https://golang.org/issue/31827 .
322 MOVD R19, 8*4(RSP)
323 MOVD R20, 8*5(RSP)
324 MOVD R21, 8*6(RSP)
325 MOVD R22, 8*7(RSP)
326 MOVD R23, 8*8(RSP)
327 MOVD R24, 8*9(RSP)
328 MOVD R25, 8*10(RSP)
329 MOVD R26, 8*11(RSP)
330 MOVD R27, 8*12(RSP)
331 MOVD g, 8*13(RSP)
332 MOVD R29, 8*14(RSP)
333 FMOVD F8, 8*15(RSP)
334 FMOVD F9, 8*16(RSP)
335 FMOVD F10, 8*17(RSP)
336 FMOVD F11, 8*18(RSP)
337 FMOVD F12, 8*19(RSP)
338 FMOVD F13, 8*20(RSP)
339 FMOVD F14, 8*21(RSP)
340 FMOVD F15, 8*22(RSP)
341
342 // this might be called in external code context,
343 // where g is not set.
344 // first save R0, because runtime·load_g will clobber it
345 MOVW R0, 8(RSP)
346 MOVBU runtime·iscgo(SB), R0
347 CMP $0, R0
348 BEQ 2(PC)
349 BL runtime·load_g(SB)
350
351 MOVD R1, 16(RSP)
352 MOVD R2, 24(RSP)
353 MOVD $runtime·sigtrampgo(SB), R0
354 BL (R0)
355
356 // Restore callee-save registers.
357 MOVD 8*4(RSP), R19
358 MOVD 8*5(RSP), R20
359 MOVD 8*6(RSP), R21
360 MOVD 8*7(RSP), R22
361 MOVD 8*8(RSP), R23
362 MOVD 8*9(RSP), R24
363 MOVD 8*10(RSP), R25
364 MOVD 8*11(RSP), R26
365 MOVD 8*12(RSP), R27
366 MOVD 8*13(RSP), g
367 MOVD 8*14(RSP), R29
368 FMOVD 8*15(RSP), F8
369 FMOVD 8*16(RSP), F9
370 FMOVD 8*17(RSP), F10
371 FMOVD 8*18(RSP), F11
372 FMOVD 8*19(RSP), F12
373 FMOVD 8*20(RSP), F13
374 FMOVD 8*21(RSP), F14
375 FMOVD 8*22(RSP), F15
376
377 RET
378
379 TEXT runtime·cgoSigtramp(SB),NOSPLIT,$0
380 MOVD $runtime·sigtramp(SB), R3
381 B (R3)
382
383 TEXT runtime·sysMmap(SB),NOSPLIT|NOFRAME,$0
384 MOVD addr+0(FP), R0
385 MOVD n+8(FP), R1
386 MOVW prot+16(FP), R2
387 MOVW flags+20(FP), R3
388 MOVW fd+24(FP), R4
389 MOVW off+28(FP), R5
390
391 MOVD $SYS_mmap, R8
392 SVC
393 CMN $4095, R0
394 BCC ok
395 NEG R0,R0
396 MOVD $0, p+32(FP)
397 MOVD R0, err+40(FP)
398 RET
399 ok:
400 MOVD R0, p+32(FP)
401 MOVD $0, err+40(FP)
402 RET
403
404 // Call the function stored in _cgo_mmap using the GCC calling convention.
405 // This must be called on the system stack.
406 TEXT runtime·callCgoMmap(SB),NOSPLIT,$0
407 MOVD addr+0(FP), R0
408 MOVD n+8(FP), R1
409 MOVW prot+16(FP), R2
410 MOVW flags+20(FP), R3
411 MOVW fd+24(FP), R4
412 MOVW off+28(FP), R5
413 MOVD _cgo_mmap(SB), R9
414 SUB $16, RSP // reserve 16 bytes for sp-8 where fp may be saved.
415 BL R9
416 ADD $16, RSP
417 MOVD R0, ret+32(FP)
418 RET
419
420 TEXT runtime·sysMunmap(SB),NOSPLIT|NOFRAME,$0
421 MOVD addr+0(FP), R0
422 MOVD n+8(FP), R1
423 MOVD $SYS_munmap, R8
424 SVC
425 CMN $4095, R0
426 BCC cool
427 MOVD R0, 0xf0(R0)
428 cool:
429 RET
430
431 // Call the function stored in _cgo_munmap using the GCC calling convention.
432 // This must be called on the system stack.
433 TEXT runtime·callCgoMunmap(SB),NOSPLIT,$0
434 MOVD addr+0(FP), R0
435 MOVD n+8(FP), R1
436 MOVD _cgo_munmap(SB), R9
437 SUB $16, RSP // reserve 16 bytes for sp-8 where fp may be saved.
438 BL R9
439 ADD $16, RSP
440 RET
441
442 TEXT runtime·madvise(SB),NOSPLIT|NOFRAME,$0
443 MOVD addr+0(FP), R0
444 MOVD n+8(FP), R1
445 MOVW flags+16(FP), R2
446 MOVD $SYS_madvise, R8
447 SVC
448 MOVW R0, ret+24(FP)
449 RET
450
451 // int64 futex(int32 *uaddr, int32 op, int32 val,
452 // struct timespec *timeout, int32 *uaddr2, int32 val2);
453 TEXT runtime·futex(SB),NOSPLIT|NOFRAME,$0
454 MOVD addr+0(FP), R0
455 MOVW op+8(FP), R1
456 MOVW val+12(FP), R2
457 MOVD ts+16(FP), R3
458 MOVD addr2+24(FP), R4
459 MOVW val3+32(FP), R5
460 MOVD $SYS_futex, R8
461 SVC
462 MOVW R0, ret+40(FP)
463 RET
464
465 // int64 clone(int32 flags, void *stk, M *mp, G *gp, void (*fn)(void));
466 TEXT runtime·clone(SB),NOSPLIT|NOFRAME,$0
467 MOVW flags+0(FP), R0
468 MOVD stk+8(FP), R1
469
470 // Copy mp, gp, fn off parent stack for use by child.
471 MOVD mp+16(FP), R10
472 MOVD gp+24(FP), R11
473 MOVD fn+32(FP), R12
474
475 MOVD R10, -8(R1)
476 MOVD R11, -16(R1)
477 MOVD R12, -24(R1)
478 MOVD $1234, R10
479 MOVD R10, -32(R1)
480
481 MOVD $SYS_clone, R8
482 SVC
483
484 // In parent, return.
485 CMP ZR, R0
486 BEQ child
487 MOVW R0, ret+40(FP)
488 RET
489 child:
490
491 // In child, on new stack.
492 MOVD -32(RSP), R10
493 MOVD $1234, R0
494 CMP R0, R10
495 BEQ good
496 MOVD $0, R0
497 MOVD R0, (R0) // crash
498
499 good:
500 // Initialize m->procid to Linux tid
501 MOVD $SYS_gettid, R8
502 SVC
503
504 MOVD -24(RSP), R12 // fn
505 MOVD -16(RSP), R11 // g
506 MOVD -8(RSP), R10 // m
507
508 CMP $0, R10
509 BEQ nog
510 CMP $0, R11
511 BEQ nog
512
513 MOVD R0, m_procid(R10)
514
515 // TODO: setup TLS.
516
517 // In child, set up new stack
518 MOVD R10, g_m(R11)
519 MOVD R11, g
520 //CALL runtime·stackcheck(SB)
521
522 nog:
523 // Call fn
524 MOVD R12, R0
525 BL (R0)
526
527 // It shouldn't return. If it does, exit that thread.
528 MOVW $111, R0
529 again:
530 MOVD $SYS_exit, R8
531 SVC
532 B again // keep exiting
533
534 TEXT runtime·sigaltstack(SB),NOSPLIT|NOFRAME,$0
535 MOVD new+0(FP), R0
536 MOVD old+8(FP), R1
537 MOVD $SYS_sigaltstack, R8
538 SVC
539 CMN $4095, R0
540 BCC ok
541 MOVD $0, R0
542 MOVD R0, (R0) // crash
543 ok:
544 RET
545
546 TEXT runtime·osyield(SB),NOSPLIT|NOFRAME,$0
547 MOVD $SYS_sched_yield, R8
548 SVC
549 RET
550
551 TEXT runtime·sched_getaffinity(SB),NOSPLIT|NOFRAME,$0
552 MOVD pid+0(FP), R0
553 MOVD len+8(FP), R1
554 MOVD buf+16(FP), R2
555 MOVD $SYS_sched_getaffinity, R8
556 SVC
557 MOVW R0, ret+24(FP)
558 RET
559
560 // int32 runtime·epollcreate(int32 size);
561 TEXT runtime·epollcreate(SB),NOSPLIT|NOFRAME,$0
562 MOVW $0, R0
563 MOVD $SYS_epoll_create1, R8
564 SVC
565 MOVW R0, ret+8(FP)
566 RET
567
568 // int32 runtime·epollcreate1(int32 flags);
569 TEXT runtime·epollcreate1(SB),NOSPLIT|NOFRAME,$0
570 MOVW flags+0(FP), R0
571 MOVD $SYS_epoll_create1, R8
572 SVC
573 MOVW R0, ret+8(FP)
574 RET
575
576 // func epollctl(epfd, op, fd int32, ev *epollEvent) int
577 TEXT runtime·epollctl(SB),NOSPLIT|NOFRAME,$0
578 MOVW epfd+0(FP), R0
579 MOVW op+4(FP), R1
580 MOVW fd+8(FP), R2
581 MOVD ev+16(FP), R3
582 MOVD $SYS_epoll_ctl, R8
583 SVC
584 MOVW R0, ret+24(FP)
585 RET
586
587 // int32 runtime·epollwait(int32 epfd, EpollEvent *ev, int32 nev, int32 timeout);
588 TEXT runtime·epollwait(SB),NOSPLIT|NOFRAME,$0
589 MOVW epfd+0(FP), R0
590 MOVD ev+8(FP), R1
591 MOVW nev+16(FP), R2
592 MOVW timeout+20(FP), R3
593 MOVD $0, R4
594 MOVD $SYS_epoll_pwait, R8
595 SVC
596 MOVW R0, ret+24(FP)
597 RET
598
599 // void runtime·closeonexec(int32 fd);
600 TEXT runtime·closeonexec(SB),NOSPLIT|NOFRAME,$0
601 MOVW fd+0(FP), R0 // fd
602 MOVD $2, R1 // F_SETFD
603 MOVD $1, R2 // FD_CLOEXEC
604 MOVD $SYS_fcntl, R8
605 SVC
606 RET
607
608 // int access(const char *name, int mode)
609 TEXT runtime·access(SB),NOSPLIT,$0-20
610 MOVD $AT_FDCWD, R0
611 MOVD name+0(FP), R1
612 MOVW mode+8(FP), R2
613 MOVD $SYS_faccessat, R8
614 SVC
615 MOVW R0, ret+16(FP)
616 RET
617
618 // int connect(int fd, const struct sockaddr *addr, socklen_t len)
619 TEXT runtime·connect(SB),NOSPLIT,$0-28
620 MOVW fd+0(FP), R0
621 MOVD addr+8(FP), R1
622 MOVW len+16(FP), R2
623 MOVD $SYS_connect, R8
624 SVC
625 MOVW R0, ret+24(FP)
626 RET
627
628 // int socket(int domain, int typ, int prot)
629 TEXT runtime·socket(SB),NOSPLIT,$0-20
630 MOVW domain+0(FP), R0
631 MOVW typ+4(FP), R1
632 MOVW prot+8(FP), R2
633 MOVD $SYS_socket, R8
634 SVC
635 MOVW R0, ret+16(FP)
636 RET
637
638 // func sbrk0() uintptr
639 TEXT runtime·sbrk0(SB),NOSPLIT,$0-8
640 // Implemented as brk(NULL).
641 MOVD $0, R0
642 MOVD $SYS_brk, R8
643 SVC
644 MOVD R0, ret+0(FP)
645 RET
646
647 TEXT runtime·sigreturn(SB),NOSPLIT,$0-0
648 RET
View as plain text