Text file src/runtime/memclr_arm.s

     1	// Inferno's libkern/memset-arm.s
     2	// https://bitbucket.org/inferno-os/inferno-os/src/default/libkern/memset-arm.s
     3	//
     4	//         Copyright © 1994-1999 Lucent Technologies Inc. All rights reserved.
     5	//         Revisions Copyright © 2000-2007 Vita Nuova Holdings Limited (www.vitanuova.com).  All rights reserved.
     6	//         Portions Copyright 2009 The Go Authors. All rights reserved.
     7	//
     8	// Permission is hereby granted, free of charge, to any person obtaining a copy
     9	// of this software and associated documentation files (the "Software"), to deal
    10	// in the Software without restriction, including without limitation the rights
    11	// to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
    12	// copies of the Software, and to permit persons to whom the Software is
    13	// furnished to do so, subject to the following conditions:
    14	//
    15	// The above copyright notice and this permission notice shall be included in
    16	// all copies or substantial portions of the Software.
    17	//
    18	// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
    19	// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
    20	// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL THE
    21	// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
    22	// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
    23	// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
    24	// THE SOFTWARE.
    25	
    26	#include "textflag.h"
    27	
    28	#define TO	R8
    29	#define TOE	R11
    30	#define N	R12
    31	#define TMP	R12				/* N and TMP don't overlap */
    32	
    33	// func memclrNoHeapPointers(ptr unsafe.Pointer, n uintptr)
    34	TEXT runtime·memclrNoHeapPointers(SB),NOSPLIT,$0-8
    35		MOVW	ptr+0(FP), TO
    36		MOVW	n+4(FP), N
    37		MOVW	$0, R0
    38	
    39		ADD	N, TO, TOE	/* to end pointer */
    40	
    41		CMP	$4, N		/* need at least 4 bytes to copy */
    42		BLT	_1tail
    43	
    44	_4align:				/* align on 4 */
    45		AND.S	$3, TO, TMP
    46		BEQ	_4aligned
    47	
    48		MOVBU.P	R0, 1(TO)		/* implicit write back */
    49		B	_4align
    50	
    51	_4aligned:
    52		SUB	$31, TOE, TMP	/* do 32-byte chunks if possible */
    53		CMP	TMP, TO
    54		BHS	_4tail
    55	
    56		MOVW	R0, R1			/* replicate */
    57		MOVW	R0, R2
    58		MOVW	R0, R3
    59		MOVW	R0, R4
    60		MOVW	R0, R5
    61		MOVW	R0, R6
    62		MOVW	R0, R7
    63	
    64	_f32loop:
    65		CMP	TMP, TO
    66		BHS	_4tail
    67	
    68		MOVM.IA.W [R0-R7], (TO)
    69		B	_f32loop
    70	
    71	_4tail:
    72		SUB	$3, TOE, TMP	/* do remaining words if possible */
    73	_4loop:
    74		CMP	TMP, TO
    75		BHS	_1tail
    76	
    77		MOVW.P	R0, 4(TO)		/* implicit write back */
    78		B	_4loop
    79	
    80	_1tail:
    81		CMP	TO, TOE
    82		BEQ	_return
    83	
    84		MOVBU.P	R0, 1(TO)		/* implicit write back */
    85		B	_1tail
    86	
    87	_return:
    88		RET

View as plain text