Text file src/pkg/runtime/sys_netbsd_386.s
1 // Copyright 2009 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4 //
5 // System calls and other sys.stuff for 386, NetBSD
6 // /usr/src/sys/kern/syscalls.master for syscall numbers.
7 //
8
9 #include "go_asm.h"
10 #include "go_tls.h"
11 #include "textflag.h"
12
13 #define CLOCK_REALTIME 0
14 #define CLOCK_MONOTONIC 3
15 #define FD_CLOEXEC 1
16 #define F_SETFD 2
17
18 #define SYS_exit 1
19 #define SYS_read 3
20 #define SYS_write 4
21 #define SYS_open 5
22 #define SYS_close 6
23 #define SYS_getpid 20
24 #define SYS_kill 37
25 #define SYS_munmap 73
26 #define SYS_madvise 75
27 #define SYS_fcntl 92
28 #define SYS_mmap 197
29 #define SYS___sysctl 202
30 #define SYS___sigaltstack14 281
31 #define SYS___sigprocmask14 293
32 #define SYS_getcontext 307
33 #define SYS_setcontext 308
34 #define SYS__lwp_create 309
35 #define SYS__lwp_exit 310
36 #define SYS__lwp_self 311
37 #define SYS__lwp_setprivate 317
38 #define SYS__lwp_kill 318
39 #define SYS__lwp_unpark 321
40 #define SYS___sigaction_sigtramp 340
41 #define SYS_kqueue 344
42 #define SYS_sched_yield 350
43 #define SYS___setitimer50 425
44 #define SYS___clock_gettime50 427
45 #define SYS___nanosleep50 430
46 #define SYS___kevent50 435
47 #define SYS____lwp_park60 478
48
49 // Exit the entire program (like C exit)
50 TEXT runtime·exit(SB),NOSPLIT,$-4
51 MOVL $SYS_exit, AX
52 INT $0x80
53 MOVL $0xf1, 0xf1 // crash
54 RET
55
56 // func exitThread(wait *uint32)
57 TEXT runtime·exitThread(SB),NOSPLIT,$0-4
58 MOVL wait+0(FP), AX
59 // We're done using the stack.
60 MOVL $0, (AX)
61 MOVL $SYS__lwp_exit, AX
62 INT $0x80
63 MOVL $0xf1, 0xf1 // crash
64 JMP 0(PC)
65
66 TEXT runtime·open(SB),NOSPLIT,$-4
67 MOVL $SYS_open, AX
68 INT $0x80
69 JAE 2(PC)
70 MOVL $-1, AX
71 MOVL AX, ret+12(FP)
72 RET
73
74 TEXT runtime·closefd(SB),NOSPLIT,$-4
75 MOVL $SYS_close, AX
76 INT $0x80
77 JAE 2(PC)
78 MOVL $-1, AX
79 MOVL AX, ret+4(FP)
80 RET
81
82 TEXT runtime·read(SB),NOSPLIT,$-4
83 MOVL $SYS_read, AX
84 INT $0x80
85 JAE 2(PC)
86 MOVL $-1, AX
87 MOVL AX, ret+12(FP)
88 RET
89
90 TEXT runtime·write(SB),NOSPLIT,$-4
91 MOVL $SYS_write, AX
92 INT $0x80
93 JAE 2(PC)
94 MOVL $-1, AX
95 MOVL AX, ret+12(FP)
96 RET
97
98 TEXT runtime·usleep(SB),NOSPLIT,$24
99 MOVL $0, DX
100 MOVL usec+0(FP), AX
101 MOVL $1000000, CX
102 DIVL CX
103 MOVL AX, 12(SP) // tv_sec - l32
104 MOVL $0, 16(SP) // tv_sec - h32
105 MOVL $1000, AX
106 MULL DX
107 MOVL AX, 20(SP) // tv_nsec
108
109 MOVL $0, 0(SP)
110 LEAL 12(SP), AX
111 MOVL AX, 4(SP) // arg 1 - rqtp
112 MOVL $0, 8(SP) // arg 2 - rmtp
113 MOVL $SYS___nanosleep50, AX
114 INT $0x80
115 RET
116
117 TEXT runtime·raise(SB),NOSPLIT,$12
118 MOVL $SYS__lwp_self, AX
119 INT $0x80
120 MOVL $0, 0(SP)
121 MOVL AX, 4(SP) // arg 1 - target
122 MOVL sig+0(FP), AX
123 MOVL AX, 8(SP) // arg 2 - signo
124 MOVL $SYS__lwp_kill, AX
125 INT $0x80
126 RET
127
128 TEXT runtime·raiseproc(SB),NOSPLIT,$12
129 MOVL $SYS_getpid, AX
130 INT $0x80
131 MOVL $0, 0(SP)
132 MOVL AX, 4(SP) // arg 1 - pid
133 MOVL sig+0(FP), AX
134 MOVL AX, 8(SP) // arg 2 - signo
135 MOVL $SYS_kill, AX
136 INT $0x80
137 RET
138
139 TEXT runtime·mmap(SB),NOSPLIT,$36
140 LEAL addr+0(FP), SI
141 LEAL 4(SP), DI
142 CLD
143 MOVSL // arg 1 - addr
144 MOVSL // arg 2 - len
145 MOVSL // arg 3 - prot
146 MOVSL // arg 4 - flags
147 MOVSL // arg 5 - fd
148 MOVL $0, AX
149 STOSL // arg 6 - pad
150 MOVSL // arg 7 - offset
151 MOVL $0, AX // top 32 bits of file offset
152 STOSL
153 MOVL $SYS_mmap, AX
154 INT $0x80
155 JAE ok
156 MOVL $0, p+24(FP)
157 MOVL AX, err+28(FP)
158 RET
159 ok:
160 MOVL AX, p+24(FP)
161 MOVL $0, err+28(FP)
162 RET
163
164 TEXT runtime·munmap(SB),NOSPLIT,$-4
165 MOVL $SYS_munmap, AX
166 INT $0x80
167 JAE 2(PC)
168 MOVL $0xf1, 0xf1 // crash
169 RET
170
171 TEXT runtime·madvise(SB),NOSPLIT,$-4
172 MOVL $SYS_madvise, AX
173 INT $0x80
174 JAE 2(PC)
175 MOVL $-1, AX
176 MOVL AX, ret+12(FP)
177 RET
178
179 TEXT runtime·setitimer(SB),NOSPLIT,$-4
180 MOVL $SYS___setitimer50, AX
181 INT $0x80
182 RET
183
184 // func walltime() (sec int64, nsec int32)
185 TEXT runtime·walltime(SB), NOSPLIT, $32
186 LEAL 12(SP), BX
187 MOVL $CLOCK_REALTIME, 4(SP) // arg 1 - clock_id
188 MOVL BX, 8(SP) // arg 2 - tp
189 MOVL $SYS___clock_gettime50, AX
190 INT $0x80
191
192 MOVL 12(SP), AX // sec - l32
193 MOVL AX, sec_lo+0(FP)
194 MOVL 16(SP), AX // sec - h32
195 MOVL AX, sec_hi+4(FP)
196
197 MOVL 20(SP), BX // nsec
198 MOVL BX, nsec+8(FP)
199 RET
200
201 // int64 nanotime(void) so really
202 // void nanotime(int64 *nsec)
203 TEXT runtime·nanotime(SB),NOSPLIT,$32
204 LEAL 12(SP), BX
205 MOVL $CLOCK_MONOTONIC, 4(SP) // arg 1 - clock_id
206 MOVL BX, 8(SP) // arg 2 - tp
207 MOVL $SYS___clock_gettime50, AX
208 INT $0x80
209
210 MOVL 16(SP), CX // sec - h32
211 IMULL $1000000000, CX
212
213 MOVL 12(SP), AX // sec - l32
214 MOVL $1000000000, BX
215 MULL BX // result in dx:ax
216
217 MOVL 20(SP), BX // nsec
218 ADDL BX, AX
219 ADCL CX, DX // add high bits with carry
220
221 MOVL AX, ret_lo+0(FP)
222 MOVL DX, ret_hi+4(FP)
223 RET
224
225 TEXT runtime·getcontext(SB),NOSPLIT,$-4
226 MOVL $SYS_getcontext, AX
227 INT $0x80
228 JAE 2(PC)
229 MOVL $0xf1, 0xf1 // crash
230 RET
231
232 TEXT runtime·sigprocmask(SB),NOSPLIT,$-4
233 MOVL $SYS___sigprocmask14, AX
234 INT $0x80
235 JAE 2(PC)
236 MOVL $0xf1, 0xf1 // crash
237 RET
238
239 TEXT sigreturn_tramp<>(SB),NOSPLIT,$0
240 LEAL 140(SP), AX // Load address of ucontext
241 MOVL AX, 4(SP)
242 MOVL $SYS_setcontext, AX
243 INT $0x80
244 MOVL $-1, 4(SP) // Something failed...
245 MOVL $SYS_exit, AX
246 INT $0x80
247
248 TEXT runtime·sigaction(SB),NOSPLIT,$24
249 LEAL sig+0(FP), SI
250 LEAL 4(SP), DI
251 CLD
252 MOVSL // arg 1 - sig
253 MOVSL // arg 2 - act
254 MOVSL // arg 3 - oact
255 LEAL sigreturn_tramp<>(SB), AX
256 STOSL // arg 4 - tramp
257 MOVL $2, AX
258 STOSL // arg 5 - vers
259 MOVL $SYS___sigaction_sigtramp, AX
260 INT $0x80
261 JAE 2(PC)
262 MOVL $0xf1, 0xf1 // crash
263 RET
264
265 TEXT runtime·sigfwd(SB),NOSPLIT,$12-16
266 MOVL fn+0(FP), AX
267 MOVL sig+4(FP), BX
268 MOVL info+8(FP), CX
269 MOVL ctx+12(FP), DX
270 MOVL SP, SI
271 SUBL $32, SP
272 ANDL $-15, SP // align stack: handler might be a C function
273 MOVL BX, 0(SP)
274 MOVL CX, 4(SP)
275 MOVL DX, 8(SP)
276 MOVL SI, 12(SP) // save SI: handler might be a Go function
277 CALL AX
278 MOVL 12(SP), AX
279 MOVL AX, SP
280 RET
281
282 // Called by OS using C ABI.
283 TEXT runtime·sigtramp(SB),NOSPLIT,$28
284 NOP SP // tell vet SP changed - stop checking offsets
285 // Save callee-saved C registers, since the caller may be a C signal handler.
286 MOVL BX, bx-4(SP)
287 MOVL BP, bp-8(SP)
288 MOVL SI, si-12(SP)
289 MOVL DI, di-16(SP)
290 // We don't save mxcsr or the x87 control word because sigtrampgo doesn't
291 // modify them.
292
293 MOVL 32(SP), BX // signo
294 MOVL BX, 0(SP)
295 MOVL 36(SP), BX // info
296 MOVL BX, 4(SP)
297 MOVL 40(SP), BX // context
298 MOVL BX, 8(SP)
299 CALL runtime·sigtrampgo(SB)
300
301 MOVL di-16(SP), DI
302 MOVL si-12(SP), SI
303 MOVL bp-8(SP), BP
304 MOVL bx-4(SP), BX
305 RET
306
307 // int32 lwp_create(void *context, uintptr flags, void *lwpid);
308 TEXT runtime·lwp_create(SB),NOSPLIT,$16
309 MOVL $0, 0(SP)
310 MOVL ctxt+0(FP), AX
311 MOVL AX, 4(SP) // arg 1 - context
312 MOVL flags+4(FP), AX
313 MOVL AX, 8(SP) // arg 2 - flags
314 MOVL lwpid+8(FP), AX
315 MOVL AX, 12(SP) // arg 3 - lwpid
316 MOVL $SYS__lwp_create, AX
317 INT $0x80
318 JCC 2(PC)
319 NEGL AX
320 MOVL AX, ret+12(FP)
321 RET
322
323 TEXT runtime·lwp_tramp(SB),NOSPLIT,$0
324
325 // Set FS to point at m->tls
326 LEAL m_tls(BX), BP
327 PUSHAL // save registers
328 PUSHL BP
329 CALL lwp_setprivate<>(SB)
330 POPL AX
331 POPAL
332
333 // Now segment is established. Initialize m, g.
334 get_tls(AX)
335 MOVL DX, g(AX)
336 MOVL BX, g_m(DX)
337
338 CALL runtime·stackcheck(SB) // smashes AX, CX
339 MOVL 0(DX), DX // paranoia; check they are not nil
340 MOVL 0(BX), BX
341
342 // more paranoia; check that stack splitting code works
343 PUSHAL
344 CALL runtime·emptyfunc(SB)
345 POPAL
346
347 // Call fn
348 CALL SI
349
350 // fn should never return
351 MOVL $0x1234, 0x1005
352 RET
353
354 TEXT runtime·sigaltstack(SB),NOSPLIT,$-8
355 MOVL $SYS___sigaltstack14, AX
356 MOVL new+0(FP), BX
357 MOVL old+4(FP), CX
358 INT $0x80
359 CMPL AX, $0xfffff001
360 JLS 2(PC)
361 INT $3
362 RET
363
364 TEXT runtime·setldt(SB),NOSPLIT,$8
365 // Under NetBSD we set the GS base instead of messing with the LDT.
366 MOVL base+4(FP), AX
367 MOVL AX, 0(SP)
368 CALL lwp_setprivate<>(SB)
369 RET
370
371 TEXT lwp_setprivate<>(SB),NOSPLIT,$16
372 // adjust for ELF: wants to use -4(GS) for g
373 MOVL base+0(FP), CX
374 ADDL $4, CX
375 MOVL $0, 0(SP) // syscall gap
376 MOVL CX, 4(SP) // arg 1 - ptr
377 MOVL $SYS__lwp_setprivate, AX
378 INT $0x80
379 JCC 2(PC)
380 MOVL $0xf1, 0xf1 // crash
381 RET
382
383 TEXT runtime·osyield(SB),NOSPLIT,$-4
384 MOVL $SYS_sched_yield, AX
385 INT $0x80
386 RET
387
388 TEXT runtime·lwp_park(SB),NOSPLIT,$-4
389 MOVL $SYS____lwp_park60, AX
390 INT $0x80
391 MOVL AX, ret+24(FP)
392 RET
393
394 TEXT runtime·lwp_unpark(SB),NOSPLIT,$-4
395 MOVL $SYS__lwp_unpark, AX
396 INT $0x80
397 MOVL AX, ret+8(FP)
398 RET
399
400 TEXT runtime·lwp_self(SB),NOSPLIT,$-4
401 MOVL $SYS__lwp_self, AX
402 INT $0x80
403 MOVL AX, ret+0(FP)
404 RET
405
406 TEXT runtime·sysctl(SB),NOSPLIT,$28
407 LEAL mib+0(FP), SI
408 LEAL 4(SP), DI
409 CLD
410 MOVSL // arg 1 - name
411 MOVSL // arg 2 - namelen
412 MOVSL // arg 3 - oldp
413 MOVSL // arg 4 - oldlenp
414 MOVSL // arg 5 - newp
415 MOVSL // arg 6 - newlen
416 MOVL $SYS___sysctl, AX
417 INT $0x80
418 JAE 4(PC)
419 NEGL AX
420 MOVL AX, ret+24(FP)
421 RET
422 MOVL $0, AX
423 MOVL AX, ret+24(FP)
424 RET
425
426 GLOBL runtime·tlsoffset(SB),NOPTR,$4
427
428 // int32 runtime·kqueue(void)
429 TEXT runtime·kqueue(SB),NOSPLIT,$0
430 MOVL $SYS_kqueue, AX
431 INT $0x80
432 JAE 2(PC)
433 NEGL AX
434 MOVL AX, ret+0(FP)
435 RET
436
437 // int32 runtime·kevent(int kq, Kevent *changelist, int nchanges, Kevent *eventlist, int nevents, Timespec *timeout)
438 TEXT runtime·kevent(SB),NOSPLIT,$0
439 MOVL $SYS___kevent50, AX
440 INT $0x80
441 JAE 2(PC)
442 NEGL AX
443 MOVL AX, ret+24(FP)
444 RET
445
446 // int32 runtime·closeonexec(int32 fd)
447 TEXT runtime·closeonexec(SB),NOSPLIT,$32
448 MOVL $SYS_fcntl, AX
449 // 0(SP) is where the caller PC would be; kernel skips it
450 MOVL fd+0(FP), BX
451 MOVL BX, 4(SP) // fd
452 MOVL $F_SETFD, 8(SP)
453 MOVL $FD_CLOEXEC, 12(SP)
454 INT $0x80
455 JAE 2(PC)
456 NEGL AX
457 RET
View as plain text