Text file src/pkg/runtime/sys_linux_mipsx.s
1 // Copyright 2016 The Go Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style
3 // license that can be found in the LICENSE file.
4
5 // +build linux
6 // +build mips mipsle
7
8 //
9 // System calls and other sys.stuff for mips, Linux
10 //
11
12 #include "go_asm.h"
13 #include "go_tls.h"
14 #include "textflag.h"
15
16 #define SYS_exit 4001
17 #define SYS_read 4003
18 #define SYS_write 4004
19 #define SYS_open 4005
20 #define SYS_close 4006
21 #define SYS_getpid 4020
22 #define SYS_kill 4037
23 #define SYS_brk 4045
24 #define SYS_fcntl 4055
25 #define SYS_mmap 4090
26 #define SYS_munmap 4091
27 #define SYS_setitimer 4104
28 #define SYS_clone 4120
29 #define SYS_sched_yield 4162
30 #define SYS_nanosleep 4166
31 #define SYS_rt_sigreturn 4193
32 #define SYS_rt_sigaction 4194
33 #define SYS_rt_sigprocmask 4195
34 #define SYS_sigaltstack 4206
35 #define SYS_madvise 4218
36 #define SYS_mincore 4217
37 #define SYS_gettid 4222
38 #define SYS_futex 4238
39 #define SYS_sched_getaffinity 4240
40 #define SYS_exit_group 4246
41 #define SYS_epoll_create 4248
42 #define SYS_epoll_ctl 4249
43 #define SYS_epoll_wait 4250
44 #define SYS_clock_gettime 4263
45 #define SYS_tgkill 4266
46 #define SYS_epoll_create1 4326
47
48 TEXT runtime·exit(SB),NOSPLIT,$0-4
49 MOVW code+0(FP), R4
50 MOVW $SYS_exit_group, R2
51 SYSCALL
52 UNDEF
53 RET
54
55 // func exitThread(wait *uint32)
56 TEXT runtime·exitThread(SB),NOSPLIT,$0-4
57 MOVW wait+0(FP), R1
58 // We're done using the stack.
59 MOVW $0, R2
60 SYNC
61 MOVW R2, (R1)
62 SYNC
63 MOVW $0, R4 // exit code
64 MOVW $SYS_exit, R2
65 SYSCALL
66 UNDEF
67 JMP 0(PC)
68
69 TEXT runtime·open(SB),NOSPLIT,$0-16
70 MOVW name+0(FP), R4
71 MOVW mode+4(FP), R5
72 MOVW perm+8(FP), R6
73 MOVW $SYS_open, R2
74 SYSCALL
75 BEQ R7, 2(PC)
76 MOVW $-1, R2
77 MOVW R2, ret+12(FP)
78 RET
79
80 TEXT runtime·closefd(SB),NOSPLIT,$0-8
81 MOVW fd+0(FP), R4
82 MOVW $SYS_close, R2
83 SYSCALL
84 BEQ R7, 2(PC)
85 MOVW $-1, R2
86 MOVW R2, ret+4(FP)
87 RET
88
89 TEXT runtime·write(SB),NOSPLIT,$0-16
90 MOVW fd+0(FP), R4
91 MOVW p+4(FP), R5
92 MOVW n+8(FP), R6
93 MOVW $SYS_write, R2
94 SYSCALL
95 BEQ R7, 2(PC)
96 MOVW $-1, R2
97 MOVW R2, ret+12(FP)
98 RET
99
100 TEXT runtime·read(SB),NOSPLIT,$0-16
101 MOVW fd+0(FP), R4
102 MOVW p+4(FP), R5
103 MOVW n+8(FP), R6
104 MOVW $SYS_read, R2
105 SYSCALL
106 BEQ R7, 2(PC)
107 MOVW $-1, R2
108 MOVW R2, ret+12(FP)
109 RET
110
111 TEXT runtime·usleep(SB),NOSPLIT,$28-4
112 MOVW usec+0(FP), R3
113 MOVW R3, R5
114 MOVW $1000000, R4
115 DIVU R4, R3
116 MOVW LO, R3
117 MOVW R3, 24(R29)
118 MOVW $1000, R4
119 MULU R3, R4
120 MOVW LO, R4
121 SUBU R4, R5
122 MOVW R5, 28(R29)
123
124 // nanosleep(&ts, 0)
125 ADDU $24, R29, R4
126 MOVW $0, R5
127 MOVW $SYS_nanosleep, R2
128 SYSCALL
129 RET
130
131 TEXT runtime·gettid(SB),NOSPLIT,$0-4
132 MOVW $SYS_gettid, R2
133 SYSCALL
134 MOVW R2, ret+0(FP)
135 RET
136
137 TEXT runtime·raise(SB),NOSPLIT,$0-4
138 MOVW $SYS_getpid, R2
139 SYSCALL
140 MOVW R2, R16
141 MOVW $SYS_gettid, R2
142 SYSCALL
143 MOVW R2, R5 // arg 2 tid
144 MOVW R16, R4 // arg 1 pid
145 MOVW sig+0(FP), R6 // arg 3
146 MOVW $SYS_tgkill, R2
147 SYSCALL
148 RET
149
150 TEXT runtime·raiseproc(SB),NOSPLIT,$0
151 MOVW $SYS_getpid, R2
152 SYSCALL
153 MOVW R2, R4 // arg 1 pid
154 MOVW sig+0(FP), R5 // arg 2
155 MOVW $SYS_kill, R2
156 SYSCALL
157 RET
158
159 TEXT runtime·setitimer(SB),NOSPLIT,$0-12
160 MOVW mode+0(FP), R4
161 MOVW new+4(FP), R5
162 MOVW old+8(FP), R6
163 MOVW $SYS_setitimer, R2
164 SYSCALL
165 RET
166
167 TEXT runtime·mincore(SB),NOSPLIT,$0-16
168 MOVW addr+0(FP), R4
169 MOVW n+4(FP), R5
170 MOVW dst+8(FP), R6
171 MOVW $SYS_mincore, R2
172 SYSCALL
173 SUBU R2, R0, R2 // caller expects negative errno
174 MOVW R2, ret+12(FP)
175 RET
176
177 // func walltime() (sec int64, nsec int32)
178 TEXT runtime·walltime(SB),NOSPLIT,$8-12
179 MOVW $0, R4 // CLOCK_REALTIME
180 MOVW $4(R29), R5
181 MOVW $SYS_clock_gettime, R2
182 SYSCALL
183 MOVW 4(R29), R3 // sec
184 MOVW 8(R29), R5 // nsec
185 MOVW $sec+0(FP), R6
186 #ifdef GOARCH_mips
187 MOVW R3, 4(R6)
188 MOVW R0, 0(R6)
189 #else
190 MOVW R3, 0(R6)
191 MOVW R0, 4(R6)
192 #endif
193 MOVW R5, nsec+8(FP)
194 RET
195
196 TEXT runtime·nanotime(SB),NOSPLIT,$8-8
197 MOVW $1, R4 // CLOCK_MONOTONIC
198 MOVW $4(R29), R5
199 MOVW $SYS_clock_gettime, R2
200 SYSCALL
201 MOVW 4(R29), R3 // sec
202 MOVW 8(R29), R5 // nsec
203 // sec is in R3, nsec in R5
204 // return nsec in R3
205 MOVW $1000000000, R4
206 MULU R4, R3
207 MOVW LO, R3
208 ADDU R5, R3
209 SGTU R5, R3, R4
210 MOVW $ret+0(FP), R6
211 #ifdef GOARCH_mips
212 MOVW R3, 4(R6)
213 #else
214 MOVW R3, 0(R6)
215 #endif
216 MOVW HI, R3
217 ADDU R4, R3
218 #ifdef GOARCH_mips
219 MOVW R3, 0(R6)
220 #else
221 MOVW R3, 4(R6)
222 #endif
223 RET
224
225 TEXT runtime·rtsigprocmask(SB),NOSPLIT,$0-16
226 MOVW how+0(FP), R4
227 MOVW new+4(FP), R5
228 MOVW old+8(FP), R6
229 MOVW size+12(FP), R7
230 MOVW $SYS_rt_sigprocmask, R2
231 SYSCALL
232 BEQ R7, 2(PC)
233 UNDEF // crash
234 RET
235
236 TEXT runtime·rt_sigaction(SB),NOSPLIT,$0-20
237 MOVW sig+0(FP), R4
238 MOVW new+4(FP), R5
239 MOVW old+8(FP), R6
240 MOVW size+12(FP), R7
241 MOVW $SYS_rt_sigaction, R2
242 SYSCALL
243 BEQ R7, 2(PC)
244 SUBU R2, R0, R2 // caller expects negative errno
245 MOVW R2, ret+16(FP)
246 RET
247
248 TEXT runtime·sigfwd(SB),NOSPLIT,$0-16
249 MOVW sig+4(FP), R4
250 MOVW info+8(FP), R5
251 MOVW ctx+12(FP), R6
252 MOVW fn+0(FP), R25
253 MOVW R29, R22
254 SUBU $16, R29
255 AND $~7, R29 // shadow space for 4 args aligned to 8 bytes as per O32 ABI
256 JAL (R25)
257 MOVW R22, R29
258 RET
259
260 TEXT runtime·sigtramp(SB),NOSPLIT,$12
261 // this might be called in external code context,
262 // where g is not set.
263 MOVB runtime·iscgo(SB), R1
264 BEQ R1, 2(PC)
265 JAL runtime·load_g(SB)
266
267 MOVW R4, 4(R29)
268 MOVW R5, 8(R29)
269 MOVW R6, 12(R29)
270 MOVW $runtime·sigtrampgo(SB), R1
271 JAL (R1)
272 RET
273
274 TEXT runtime·cgoSigtramp(SB),NOSPLIT,$0
275 JMP runtime·sigtramp(SB)
276
277 TEXT runtime·mmap(SB),NOSPLIT,$20-32
278 MOVW addr+0(FP), R4
279 MOVW n+4(FP), R5
280 MOVW prot+8(FP), R6
281 MOVW flags+12(FP), R7
282 MOVW fd+16(FP), R8
283 MOVW off+20(FP), R9
284 MOVW R8, 16(R29)
285 MOVW R9, 20(R29)
286
287 MOVW $SYS_mmap, R2
288 SYSCALL
289 BEQ R7, ok
290 MOVW $0, p+24(FP)
291 MOVW R2, err+28(FP)
292 RET
293 ok:
294 MOVW R2, p+24(FP)
295 MOVW $0, err+28(FP)
296 RET
297
298 TEXT runtime·munmap(SB),NOSPLIT,$0-8
299 MOVW addr+0(FP), R4
300 MOVW n+4(FP), R5
301 MOVW $SYS_munmap, R2
302 SYSCALL
303 BEQ R7, 2(PC)
304 UNDEF // crash
305 RET
306
307 TEXT runtime·madvise(SB),NOSPLIT,$0-16
308 MOVW addr+0(FP), R4
309 MOVW n+4(FP), R5
310 MOVW flags+8(FP), R6
311 MOVW $SYS_madvise, R2
312 SYSCALL
313 MOVW R2, ret+12(FP)
314 RET
315
316 // int32 futex(int32 *uaddr, int32 op, int32 val, struct timespec *timeout, int32 *uaddr2, int32 val2);
317 TEXT runtime·futex(SB),NOSPLIT,$20-28
318 MOVW addr+0(FP), R4
319 MOVW op+4(FP), R5
320 MOVW val+8(FP), R6
321 MOVW ts+12(FP), R7
322
323 MOVW addr2+16(FP), R8
324 MOVW val3+20(FP), R9
325
326 MOVW R8, 16(R29)
327 MOVW R9, 20(R29)
328
329 MOVW $SYS_futex, R2
330 SYSCALL
331 BEQ R7, 2(PC)
332 SUBU R2, R0, R2 // caller expects negative errno
333 MOVW R2, ret+24(FP)
334 RET
335
336
337 // int32 clone(int32 flags, void *stk, M *mp, G *gp, void (*fn)(void));
338 TEXT runtime·clone(SB),NOSPLIT|NOFRAME,$0-24
339 MOVW flags+0(FP), R4
340 MOVW stk+4(FP), R5
341 MOVW R0, R6 // ptid
342 MOVW R0, R7 // tls
343
344 // O32 syscall handler unconditionally copies arguments 5-8 from stack,
345 // even for syscalls with less than 8 arguments. Reserve 32 bytes of new
346 // stack so that any syscall invoked immediately in the new thread won't fail.
347 ADD $-32, R5
348
349 // Copy mp, gp, fn off parent stack for use by child.
350 MOVW mp+8(FP), R16
351 MOVW gp+12(FP), R17
352 MOVW fn+16(FP), R18
353
354 MOVW $1234, R1
355
356 MOVW R16, 0(R5)
357 MOVW R17, 4(R5)
358 MOVW R18, 8(R5)
359
360 MOVW R1, 12(R5)
361
362 MOVW $SYS_clone, R2
363 SYSCALL
364 BEQ R7, 2(PC)
365 SUBU R2, R0, R2 // caller expects negative errno
366
367 // In parent, return.
368 BEQ R2, 3(PC)
369 MOVW R2, ret+20(FP)
370 RET
371
372 // In child, on new stack.
373 // Check that SP is as we expect
374 NOP R29 // tell vet R29/SP changed - stop checking offsets
375 MOVW 12(R29), R16
376 MOVW $1234, R1
377 BEQ R16, R1, 2(PC)
378 MOVW (R0), R0
379
380 // Initialize m->procid to Linux tid
381 MOVW $SYS_gettid, R2
382 SYSCALL
383
384 MOVW 0(R29), R16 // m
385 MOVW 4(R29), R17 // g
386 MOVW 8(R29), R18 // fn
387
388 BEQ R16, nog
389 BEQ R17, nog
390
391 MOVW R2, m_procid(R16)
392
393 // In child, set up new stack
394 MOVW R16, g_m(R17)
395 MOVW R17, g
396
397 // TODO(mips32): doesn't have runtime·stackcheck(SB)
398
399 nog:
400 // Call fn
401 ADDU $32, R29
402 JAL (R18)
403
404 // It shouldn't return. If it does, exit that thread.
405 ADDU $-32, R29
406 MOVW $0xf4, R4
407 MOVW $SYS_exit, R2
408 SYSCALL
409 UNDEF
410
411 TEXT runtime·sigaltstack(SB),NOSPLIT,$0
412 MOVW new+0(FP), R4
413 MOVW old+4(FP), R5
414 MOVW $SYS_sigaltstack, R2
415 SYSCALL
416 BEQ R7, 2(PC)
417 UNDEF // crash
418 RET
419
420 TEXT runtime·osyield(SB),NOSPLIT,$0
421 MOVW $SYS_sched_yield, R2
422 SYSCALL
423 RET
424
425 TEXT runtime·sched_getaffinity(SB),NOSPLIT,$0-16
426 MOVW pid+0(FP), R4
427 MOVW len+4(FP), R5
428 MOVW buf+8(FP), R6
429 MOVW $SYS_sched_getaffinity, R2
430 SYSCALL
431 BEQ R7, 2(PC)
432 SUBU R2, R0, R2 // caller expects negative errno
433 MOVW R2, ret+12(FP)
434 RET
435
436 // int32 runtime·epollcreate(int32 size);
437 TEXT runtime·epollcreate(SB),NOSPLIT,$0-8
438 MOVW size+0(FP), R4
439 MOVW $SYS_epoll_create, R2
440 SYSCALL
441 BEQ R7, 2(PC)
442 SUBU R2, R0, R2 // caller expects negative errno
443 MOVW R2, ret+4(FP)
444 RET
445
446 // int32 runtime·epollcreate1(int32 flags);
447 TEXT runtime·epollcreate1(SB),NOSPLIT,$0-8
448 MOVW flags+0(FP), R4
449 MOVW $SYS_epoll_create1, R2
450 SYSCALL
451 BEQ R7, 2(PC)
452 SUBU R2, R0, R2 // caller expects negative errno
453 MOVW R2, ret+4(FP)
454 RET
455
456 // func epollctl(epfd, op, fd int32, ev *epollEvent) int
457 TEXT runtime·epollctl(SB),NOSPLIT,$0-20
458 MOVW epfd+0(FP), R4
459 MOVW op+4(FP), R5
460 MOVW fd+8(FP), R6
461 MOVW ev+12(FP), R7
462 MOVW $SYS_epoll_ctl, R2
463 SYSCALL
464 SUBU R2, R0, R2 // caller expects negative errno
465 MOVW R2, ret+16(FP)
466 RET
467
468 // int32 runtime·epollwait(int32 epfd, EpollEvent *ev, int32 nev, int32 timeout);
469 TEXT runtime·epollwait(SB),NOSPLIT,$0-20
470 MOVW epfd+0(FP), R4
471 MOVW ev+4(FP), R5
472 MOVW nev+8(FP), R6
473 MOVW timeout+12(FP), R7
474 MOVW $SYS_epoll_wait, R2
475 SYSCALL
476 BEQ R7, 2(PC)
477 SUBU R2, R0, R2 // caller expects negative errno
478 MOVW R2, ret+16(FP)
479 RET
480
481 // void runtime·closeonexec(int32 fd);
482 TEXT runtime·closeonexec(SB),NOSPLIT,$0-4
483 MOVW fd+0(FP), R4 // fd
484 MOVW $2, R5 // F_SETFD
485 MOVW $1, R6 // FD_CLOEXEC
486 MOVW $SYS_fcntl, R2
487 SYSCALL
488 RET
489
490 // func sbrk0() uintptr
491 TEXT runtime·sbrk0(SB),NOSPLIT,$0-4
492 // Implemented as brk(NULL).
493 MOVW $0, R4
494 MOVW $SYS_brk, R2
495 SYSCALL
496 MOVW R2, ret+0(FP)
497 RET
498
499 TEXT runtime·access(SB),$0-12
500 BREAK // unimplemented, only needed for android; declared in stubs_linux.go
501 MOVW R0, ret+8(FP) // for vet
502 RET
503
504 TEXT runtime·connect(SB),$0-16
505 BREAK // unimplemented, only needed for android; declared in stubs_linux.go
506 MOVW R0, ret+12(FP) // for vet
507 RET
508
509 TEXT runtime·socket(SB),$0-16
510 BREAK // unimplemented, only needed for android; declared in stubs_linux.go
511 MOVW R0, ret+12(FP) // for vet
512 RET
View as plain text